martes, 27 de junio de 2017

Localizar última celda con texto

Al hilo de esta entrada del blog publicada hace algún tiempo, donde se veía como identificar la última celda con un dato numérico, un lector consultaba la manera de lograr lo mismo en caso de que la celda contuviera un texto.

Aprovecharemos para ver diferentes formulaciones que me permitirán localizar (y recuperar) las últimas celdas ocupadas, ya sena con texto o con número.

Localizar última celda con texto



Empezaremos respondiendo a lector.
Para localizar la última celda con texto, obviando valores numéricos, podríamos aplicar la fórmula:
=COINCIDIR(REPETIR("z";255);A:A)
al omitir en COINCIDIR el tercer argumento '[tipo_coincidencia]' estamos indicando, en realidad, que busque cualquier cosa similar a 255 'zetas', ya que damos por sentado no existe ningún tipo de orden en los datos distribuidos.


Con un sencillo INDICE, a partir del dato anterior, conseguimos el valor de la celda con texto:
=INDICE(A:A;COINCIDIR(REPETIR("z";255);A:A))


Para localizar la última celda con valore, además de los ya visto en el post referido al inicio:
-para identificar la fila: =COINCIDIR(9,9E+307;A:A;1)
-para recuperar el valor:=INDICE(A:A;COINCIDIR(9,9E+307;A:A;1))

Pero también:
-para identificar la fila: =BUSCAR(2;1/(A:A<>"");FILA(A:A))
-para recuperar el valor: =BUSCAR(2;1/(NO(ESBLANCO(A:A)));A:A)

O estas matriciales:
-para identificar la fila {=MAX((A:A<>"")*(FILA(A:A)))}
-para recuperar el valor: {=INDICE(A:A;MAX((A:A<>"")*(FILA(A:A))))}

Tal como se veía en la primera imagen del post.

En el caso que la última celda tuviera un dato tipo texto, todos excepto el primer método son capaces de recuperar dicho dato:
Solo recupera la última celda con número, obviando celdas con texto...
-para identificar la fila: =COINCIDIR(9,9E+307;A:A;1)
-para recuperar el valor:=INDICE(A:A;COINCIDIR(9,9E+307;A:A;1))

Localizar última celda con texto

1 comentario:

Nota: solo los miembros de este blog pueden publicar comentarios.